5 PRINT"[147]"
10 PRINTTAB(9)"DISK DIRECTORY PRINTER"
15 PRINTTAB(9)"     BY BOB SWIFT     "
20 PRINT"INSERT DISK AND PRESS 'P'"
30 PRINT"OR PRESS 'Q' TO END PROGRAM."
40 GETA$:IFA$<>"P"ANDA$<>"Q"THEN40
50 PRINT"[147]PRINTING DISK DIRECTORY"
60 IFA$="P"THENGOSUB1000:GOTO5
70 PRINT"[147]";:END
1000 OPEN1,8,15,"I0":CLOSE1
1010 OPEN1,8,0,"$0"
1020 N$=CHR$(0)
1030 GET#1,A$,A$
1031 GET#1,A$:IFA$<>CHR$(34)THEN1031:REM STRIP OFF CHARACTERS UNTIL QUOTES
1032 OPEN4,4:PRINT#4,"@ME";
1033 REM SET LH MARGIN, EMPHASIZED AND DOUBLE WIDE CHARACTERS ON PRINTER
1034 GET#1,A$:IFA$<>CHR$(34)THENPRINT#4,A$;:GOTO1034:REM PRINT TITLE ONLY
1035 GET#1,A$:IFA$<>""THEN1035:REM DISREGARD REMAINDER OF HEADER
1036 PRINT#4," ":PRINT#4," ":REM PRINT TWO BLANK LINES
1040 GET#1,A$,A$:IFA$=""THENCLOSE1:FORI=1TO3:PRINT#4," ":NEXT
1041 IFA$=""THENPRINT#4,"@":CLOSE4:RETURN:REM INITIALIZE PRINTER CONDITIONS
1050 GET#1,A$,B$ :REM # OF BLOCKS
1060 PRINT#4,ASC(A$+N$)+ASC(B$+N$)*256;
1070 GET#1,A$:IFA$=""THENPRINT#4," ":GOTO1040
1080 PRINT#4,A$;:GOTO1070
1100 REM:                             :
1101 REM:    DISK DIRECTORY PRINTER   :
1102 REM:              BY             :
1103 REM:          BOB SWIFT          :
1104 REM:                             :
1105 REM:   THIS PROGRAM WAS WRITTEN  :
1106 REM:   TO RUN WITH A COMMODORE   :
1107 REM:   64 COMPUTER, A GEMINI-10X :
1108 REM:   PRINTER, AND A 1541 DISK  :
1109 REM:   DRIVE. YOUR SYSTEM MAY    :
1110 REM:   VARY AND WILL PROBABLY    :
1111 REM:   REQUIRE SOME CHANGES TO   :
1112 REM:   THE PRINTER CODES. THESE  :
1113 REM:   SHOULD BE EASY TO FIND.   :
1114 REM:                             :
1115 REM:   I HOPE THAT YOU FIND THIS :
1116 REM:   PROGRAM TO BE AS USEFUL   :
1117 REM:   FOR DIRECTORY HARD COPIES :
1118 REM:   AS I HAVE.                :
1119 REM:                             :
1120 REM:   HAPPY COMPUTING!          :
1121 REM:                             :
1122 REM:                             :